ENIB 2026 : Enibel

Introduction

Dans le cadre de notre intersemestre, nous participons au hackathon « Hack the POCL », organisé par Les Petits Débrouillards et Les Fabriques du Ponant.

L’objectif de ce hackathon est de rendre des données tangibles en inventant un POCL : un Petit Objet Connecté Ludique.

Notre projet doit également être documenté, c’est pourquoi ce wiki a été créé, afin de retracer la genèse et l’évolution de notre travail.

Nous avons choisi de concevoir un décibelmètre capable d’allumer différentes LED en fonction du niveau sonore capté par un micro.

Ce dispositif peut avoir plusieurs usages, le plus évident étant une utilisation en salle de classe.

Une fois le système installé, une limite de décibels sera définie dans le code que nous fournirons, afin de déclencher l’allumage des LED selon le niveau de bruit. 3 niveaux :

• Vert : le niveau sonore est faible
• Jaune : le niveau sonore est assez élevé
• Rouge : le niveau sonore est très élevé

Équipe

Voici notre équipe :

À gauche : Léïa et Maël

À droite : Arthur et Alexis

Ainsi que Mael, non présent lors de la photo

Nous sommes tous les cinq des étudiant·e·s de 3e année de l'ENIB

Outils et matériel

Pour réaliser ce projet, nous avons besoin :

• Un ESP32S (ou node MCU_32S)
• Un ESP32S 38P
• Un panneau LED 16x16
• Des câbles Dupont
• Un micro INMP441

Fichiers à joindre

Code Arduino

  1  
  2 //Librairie
  3 #include <Adafruit_NeoPixel.h>
  4 #include <driver/i2s.h>
  5 
  6 //Configuration
  7 ///Leds
  8 #define W2812_PIN 27 //Broche du Din du panneau led 
  9 #define WS2812_PIXELS_NUM 256 // Nombres de leds
 10 ///Micro
 11 #define I2S_WS 25 //GPIO 25
 12 #define I2S_SD 32 //GPIO 32
 13 #define I2S_SCK 33 //GPIO 33
 14 
 15 //Matrice
 16 Adafruit_NeoPixel ledStrip(WS2812_PIXELS_NUM, W2812_PIN, NEO_GRB + NEO_KHZ800); 
 17 // Crée l'instance ledStrip avec 256 LED/pixels sur la sortie GPIO27->PIN27 du microcontrôleur. La communication se fera en GRB (Green, Red, Blue) à 800kHZ
 18 
 19 //Variable systèmes
 20 ///Luminosité
 21 const int luminosite = 10;
 22 ///Couleurs codées en (red, green, blue)
 23 uint32_t white = ledStrip.Color(255, 255, 255); // Blanc
 24 uint32_t green = ledStrip.Color(0, 255, 0); // Vert
 25 uint32_t red = ledStrip.Color(255, 0, 0); // Rouge
 26 uint32_t yellow = ledStrip.Color(255, 255, 0); // Jaune
 27 uint32_t marine_blue = ledStrip.Color(46, 62, 115); // Bleu marine
 28 ///Seuils son
 29 const int seuil_orange = 70; //dB -> Jaune
 30 const int seuil_rouge = 90; //dB -> Rouge
 31 const int GAIN_CALIBRATION = 20;
 32 ///Variable micro
 33 unsigned long lastAudioRead = 0;
 34 float dB_cached = 0;
 35 ///Dessins
 36 // On utilise uint16_t car il y a 16 bits (pixels) par ligne
 37 const uint16_t faceHappy[16] = {
 38   0b1111111111111111,
 39   0b1111100000011111,
 40   0b1111011111101111,
 41   0b1110111111110111,
 42   0b1101111111111011,
 43   0b1011100111001101, // Yeux
 44   0b1011100111001101, // Yeux
 45   0b1011111111111101,
 46   0b1011111111111101,
 47   0b1011011111101101, // Début sourire
 48   0b1011101111011101,
 49   0b1101110000111011,
 50   0b1110111111110111,
 51   0b1111011111101111,
 52   0b1111100000011111,
 53   0b1111111111111111
 54 };
 55 const uint16_t faceNeutral[16] = {
 56   0b1111111111111111,
 57   0b1111100000011111,
 58   0b1111011111101111,
 59   0b1110111111110111,
 60   0b1101111111111011,
 61   0b1011100111001101, // Yeux
 62   0b1011100111001101, // Yeux
 63   0b1011111111111101,
 64   0b1011111111111101,
 65   0b1011111111111101,
 66   0b1011000000001101, // Bouche droite
 67   0b1101111111111011,
 68   0b1110111111110111,
 69   0b1111011111101111,
 70   0b1111100000011111,
 71   0b1111111111111111
 72 };
 73 const uint16_t faceSad[16] = {
 74   0b1111111111111111,
 75   0b1111100000011111,
 76   0b1111011111101111,
 77   0b1110111111110111,
 78   0b1101111111111011,
 79   0b1011100111001101, // Yeux
 80   0b1011100111001101, // Yeux
 81   0b1011111111111101,
 82   0b1011111111111101,
 83   0b1011110000111101, // Bouche triste
 84   0b1011101111011101,
 85   0b1101011111101011,
 86   0b1110111111110111,
 87   0b1111011111101111,
 88   0b1111100000011111,
 89   0b1111111111111111
 90 };
 91 
 92 
 93 
 94 
 95 
 96 
 97 
 98 
 99 int i;
100 
101 
102 
103 void setup() {
104   // put your setup code here, to run once:
105   Serial.begin(115200);
106   ledStrip.begin();
107   ledStrip.setBrightness(luminosite);
108   setupI2S();
109   Serial.println("BOOT OK");
110 }
111 
112 void loop() {
113 
114   // --- Lecture audio toutes les 100 ms ---
115   if (millis() - lastAudioRead > 100) {
116     dB_cached = readDecibels();
117     lastAudioRead = millis();
118     Serial.println(dB_cached);
119   }
120 
121   // --- Affichage ---
122   if (dB_cached >= seuil_rouge) {
123     afficherDessin(faceSad, red);
124   }
125   else if (dB_cached >= seuil_orange) {
126     afficherDessin(faceNeutral, yellow);
127   }
128   else {
129     afficherDessin(faceHappy, green);
130   }
131 
132   delay(10);   // laisse respirer FreeRTOS
133   yield();     // nourrit le watchdog
134   Serial.println("RUNNING");
135   delay(1000);
136 }
137 
138 //Fonction d'affichage en 16x16
139 void afficherDessin(const uint16_t dessin[], uint32_t couleur){
140   ledStrip.clear();
141   for (int y = 0; y<16; y++){
142     for (int x = 0; x<16; x++){
143       //On verif le bit x dans la ligne y ( en partant de la gauche)
144       if ((dessin[y]>>(15-x)) & 0x01){
145         int index;
146         // Logique serpentin pour largueur 16
147         if (y%2 ==0){
148           index = (y * 16) + x;
149         }else{
150           index = (y*16) + (15 - x);
151         }
152         ledStrip.setPixelColor(index, couleur);
153       }
154     }
155   }
156   ledStrip.show();
157 }
158 
159 //Fonction MICRO (I2S)
160 void setupI2S() {
161   const i2s_config_t i2s_config = {
162     .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX),
163     .sample_rate = 44100,
164     .bits_per_sample = I2S_BITS_PER_SAMPLE_32BIT,
165     .channel_format = I2S_CHANNEL_FMT_ONLY_LEFT,
166     .communication_format = (i2s_comm_format_t)(I2S_COMM_FORMAT_I2S | I2S_COMM_FORMAT_I2S_MSB),
167     .intr_alloc_flags = ESP_INTR_FLAG_LEVEL1,
168     .dma_buf_count = 8,
169     .dma_buf_len = 64
170   };
171   i2s_driver_install(I2S_NUM_0, &i2s_config, 0, NULL);
172   const i2s_pin_config_t pins = {.bck_io_num = I2S_SCK, .ws_io_num = I2S_WS, .data_out_num = -1, .data_in_num = I2S_SD};
173   i2s_set_pin(I2S_NUM_0, &pins);
174   i2s_zero_dma_buffer(I2S_NUM_0);
175   delay(10);
176 }
177 
178 float readDecibels() {
179   static int32_t samples[128];
180   size_t bytesRead = 0;
181 
182   esp_err_t result = i2s_read(
183     I2S_NUM_0,
184     samples,
185     sizeof(samples),
186     &bytesRead,
187     20 / portTICK_PERIOD_MS
188   );
189 
190   if (result != ESP_OK || bytesRead < 16) {
191     return dB_cached;  // garde l’ancienne valeur
192   }
193 
194   long long sum = 0;
195   int count = bytesRead / 4;
196 
197   for (int i = 0; i < count; i++) {
198     int32_t val = samples[i] >> 14;
199     sum += (int64_t)val * val;
200   }
201 
202   float rms = sqrt((float)sum / count);
203   if (rms <= 0) return dB_cached;
204 
205   return 20.0 * log10(rms) + GAIN_CALIBRATION;
206 }

Schéma de branchement

Étapes de fabrication

Ce projet est assez simple et nécessite peu d'étapes :

Étape 1

Tout d'abord, vérifiez le matériel : que les pins soient en bon état, qu'il n'y ait pas de câble sectionné, pas de LED cassé…

Pour l'Arduino, il faut connecter l'ESP32S à votre ordinateur et également avoir l'application Arduino et leurs pilotes (Adafruit DMA neopixel library par Adafruit). Pour plus de détails, référez vous vers ce lien : https://www.wikidebrouillard.org/wiki/Utiliser_l%27ESP32_avec_le_logiciel_Arduino

Étape 2

Ouvrez l'application Arduino et copiez le code fourni.

Faites le branchement également fourni.

Étape 3

Vous pouvez modifiez dans le code les différents paramètres mis en valeur par défaut pour changer les niveaux de décibels où les LEDs s'activent.

Vous pouvez également changer pour adapter à un panneau LED plus petit ou plus grand.

De même pour l'affichage ainsi que les couleurs qui s'activeront.

Notre histoire

Après avoir réfléchis a plusieurs idées, nous sommes partis sur un décibelmètre capable d’allumer différentes LED en fonction du niveau sonore capté par un micro.

Pour cela, nous étions parti sur des LEDs polarisées mais après une demande au magasin des petits débrouillards, nous avons eu un panneau LED ce qui nous arrange pour le résultat final. Nous voulons faire un smiley pour le cas d'une salle de classe.

Un problème que nous avons rencontré est le branchement du panneau LED qui ne marchait sur aucun des appareils de l'équipe et le téléversement du code sur l'ESP32S avec l'erreur

Problème

rstx0x8 (TG1WDT_SYS_RESET)

Solution

Sources et documentation complémentaire

• Rédаctiоn et illustratiоn :
  

Pоur tоus vоs trаvauх, qu'ils sоient écrits оu visuels, l'utilisatiоn de l'intеlligеnce artificiеllе générativе, que сe sоit pоur le teхte оu les images, n'еst pas conseillé.

• Prоgrammаtiоn :
  

En сe qui cоncernе la prоgrаmmatiоn, il est еssentiеl de ne pаs faire dе l'IA vоtrе prеmier rеcоurs. Cоncеntrеz-vоus d'abоrd sur vоtre prоpre lоgiquе, votre experience еt lеs ressоurcеs disponibles.

• Transpаrence et dосumеntatiоn :
  

Si vоus utilisеz l'IA pоur déblоquer оu améliоrеr une pаrtiе de vоtre cоdе, il est cruciаl de l'indiquеr сlairеmеnt dans vоtre dосumentatiоn tеchniquе.

• Traçabilité :
  

Chаque ехtrait de cоde généré avес l'аidе de l'IA dоit êtrе accоmpagné de la sоurce, ainsi que du prоmpt eхact qui a été utilisé pоur sа créatiоn, afin d'аssurеr une évaluatiоn clаire dе vоtre prоcessus.

Élément de présentation