ENIB 2026 : Enibel

Introduction

Dans le cadre de notre intersemestre, nous participons au hackathon « Hack the POCL », organisé par Les Petits Débrouillards et Les Fabriques du Ponant.

L’objectif de ce hackathon est de rendre des données tangibles en inventant un POCL : un Petit Objet Connecté Ludique.

Notre projet doit également être documenté, c’est pourquoi ce wiki a été créé, afin de retracer la genèse et l’évolution de notre travail.

Nous avons choisi de concevoir un décibelmètre capable d’allumer différentes LED en fonction du niveau sonore capté par un micro.

Ce dispositif peut avoir plusieurs usages, le plus évident étant une utilisation en salle de classe.

Une fois le système installé, une limite de décibels sera définie dans le code que nous fournirons, afin de déclencher l’allumage des LED selon le niveau de bruit. 3 niveaux :

• Vert : le niveau sonore est faible
• Jaune : le niveau sonore est assez élevé
• Rouge : le niveau sonore est très élevé

Équipe

Voici notre équipe :

À gauche : Léïa et Maël

À droite : Arthur et Alexis

Ainsi que Mael, non présent lors de la photo

Nous sommes tous les cinq des étudiant·e·s de 3e année de l'ENIB

Outils et matériel

Pour réaliser ce projet, nous avons besoin :

• Un ESP32S (ou node MCU_32S)
• Un ESP32S 38P
• Un panneau LED 16x16
• Des câbles Dupont
• Un micro INMP441

Fichiers à joindre

Code Arduino

  1  
  2 
  3 //Librairie
  4 #include <Adafruit_NeoPixel.h>
  5 #include <driver/i2s.h>
  6 
  7 //Configuration
  8 ///Leds
  9 #define W2812_PIN 27 //Broche du Din du panneau led 
 10 #define WS2812_PIXELS_NUM 256 // Nombres de leds
 11 ///Micro
 12 #define I2S_WS 25 //GPIO 25
 13 #define I2S_SD 32 //GPIO 32
 14 #define I2S_SCK 33 //GPIO 33
 15 
 16 //Matrice
 17 Adafruit_NeoPixel ledStrip(WS2812_PIXELS_NUM, W2812_PIN, NEO_GRB + NEO_KHZ800); 
 18 // Crée l'instance ledStrip avec 256 LED/pixels sur la sortie GPIO27->PIN27 du microcontrôleur. La communication se fera en GRB (Green, Red, Blue) à 800kHZ
 19 
 20 //Variable systèmes
 21 ///Luminosité
 22 const int luminosite = 10;
 23 ///Couleurs codées en (red, green, blue)
 24 uint32_t white = ledStrip.Color(255, 255, 255); // Blanc
 25 uint32_t green = ledStrip.Color(0, 255, 0); // Vert
 26 uint32_t red = ledStrip.Color(255, 0, 0); // Rouge
 27 uint32_t yellow = ledStrip.Color(255, 255, 0); // Jaune
 28 uint32_t marine_blue = ledStrip.Color(46, 62, 115); // Bleu marine
 29 ///Seuils son
 30 const int seuil_orange = 70; //dB -> Jaune
 31 const int seuil_rouge = 90; //dB -> Rouge
 32 const int GAIN_CALIBRATION = 20;
 33 ///Variable micro
 34 unsigned long lastAudioRead = 0;
 35 float dB_cached = 0;
 36 ///Dessins
 37 // On utilise uint16_t car il y a 16 bits (pixels) par ligne
 38 const uint16_t faceHappy[16] = {
 39   0b1111111111111111,
 40   0b1111100000011111,
 41   0b1111011111101111,
 42   0b1110111111110111,
 43   0b1101111111111011,
 44   0b1011100111001101, // Yeux
 45   0b1011100111001101, // Yeux
 46   0b1011111111111101,
 47   0b1011111111111101,
 48   0b1011011111101101, // Début sourire
 49   0b1011101111011101,
 50   0b1101110000111011,
 51   0b1110111111110111,
 52   0b1111011111101111,
 53   0b1111100000011111,
 54   0b1111111111111111
 55 };
 56 const uint16_t faceNeutral[16] = {
 57   0b1111111111111111,
 58   0b1111100000011111,
 59   0b1111011111101111,
 60   0b1110111111110111,
 61   0b1101111111111011,
 62   0b1011100111001101, // Yeux
 63   0b1011100111001101, // Yeux
 64   0b1011111111111101,
 65   0b1011111111111101,
 66   0b1011111111111101,
 67   0b1011000000001101, // Bouche droite
 68   0b1101111111111011,
 69   0b1110111111110111,
 70   0b1111011111101111,
 71   0b1111100000011111,
 72   0b1111111111111111
 73 };
 74 const uint16_t faceSad[16] = {
 75   0b1111111111111111,
 76   0b1111100000011111,
 77   0b1111011111101111,
 78   0b1110111111110111,
 79   0b1101111111111011,
 80   0b1011100111001101, // Yeux
 81   0b1011100111001101, // Yeux
 82   0b1011111111111101,
 83   0b1011111111111101,
 84   0b1011110000111101, // Bouche triste
 85   0b1011101111011101,
 86   0b1101011111101011,
 87   0b1110111111110111,
 88   0b1111011111101111,
 89   0b1111100000011111,
 90   0b1111111111111111
 91 };
 92 
 93 
 94 
 95 
 96 
 97 
 98 
 99 
100 int i;
101 
102 
103 
104 void setup() {
105   // put your setup code here, to run once:
106   Serial.begin(115200);
107   ledStrip.begin();
108   ledStrip.setBrightness(luminosite);
109   setupI2S();
110   Serial.println("BOOT OK");
111 }
112 
113 void loop() {
114 
115   // --- Lecture audio toutes les 100 ms ---
116   if (millis() - lastAudioRead > 100) {
117     dB_cached = readDecibels();
118     lastAudioRead = millis();
119     Serial.println(dB_cached);
120   }
121 
122   // --- Affichage ---
123   if (dB_cached >= seuil_rouge) {
124     afficherDessin(faceSad, red);
125   }
126   else if (dB_cached >= seuil_orange) {
127     afficherDessin(faceNeutral, yellow);
128   }
129   else {
130     afficherDessin(faceHappy, green);
131   }
132 
133   delay(10);   // laisse respirer FreeRTOS
134   yield();     // nourrit le watchdog
135   Serial.println("RUNNING");
136   delay(1000);
137 }
138 
139 //Fonction d'affichage en 16x16
140 void afficherDessin(const uint16_t dessin[], uint32_t couleur){
141   ledStrip.clear();
142   for (int y = 0; y<16; y++){
143     for (int x = 0; x<16; x++){
144       //On verif le bit x dans la ligne y ( en partant de la gauche)
145       if ((dessin[y]>>(15-x)) & 0x01){
146         int index;
147         // Logique serpentin pour largueur 16
148         if (y%2 ==0){
149           index = (y * 16) + x;
150         }else{
151           index = (y*16) + (15 - x);
152         }
153         ledStrip.setPixelColor(index, couleur);
154       }
155     }
156   }
157   ledStrip.show();
158 }
159 
160 //Fonction MICRO (I2S)
161 void setupI2S() {
162   const i2s_config_t i2s_config = {
163     .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX),
164     .sample_rate = 44100,
165     .bits_per_sample = I2S_BITS_PER_SAMPLE_32BIT,
166     .channel_format = I2S_CHANNEL_FMT_ONLY_LEFT,
167     .communication_format = (i2s_comm_format_t)(I2S_COMM_FORMAT_I2S | I2S_COMM_FORMAT_I2S_MSB),
168     .intr_alloc_flags = ESP_INTR_FLAG_LEVEL1,
169     .dma_buf_count = 8,
170     .dma_buf_len = 64
171   };
172   i2s_driver_install(I2S_NUM_0, &i2s_config, 0, NULL);
173   const i2s_pin_config_t pins = {.bck_io_num = I2S_SCK, .ws_io_num = I2S_WS, .data_out_num = -1, .data_in_num = I2S_SD};
174   i2s_set_pin(I2S_NUM_0, &pins);
175   i2s_zero_dma_buffer(I2S_NUM_0);
176   delay(10);
177 }
178 
179 float readDecibels() {
180   static int32_t samples[128];
181   size_t bytesRead = 0;
182 
183   esp_err_t result = i2s_read(
184     I2S_NUM_0,
185     samples,
186     sizeof(samples),
187     &bytesRead,
188     20 / portTICK_PERIOD_MS
189   );
190 
191   if (result != ESP_OK || bytesRead < 16) {
192     return dB_cached;  // garde l’ancienne valeur
193   }
194 
195   long long sum = 0;
196   int count = bytesRead / 4;
197 
198   for (int i = 0; i < count; i++) {
199     int32_t val = samples[i] >> 14;
200     sum += (int64_t)val * val;
201   }
202 
203   float rms = sqrt((float)sum / count);
204   if (rms <= 0) return dB_cached;
205 
206   return 20.0 * log10(rms) + GAIN_CALIBRATION;
207 }

Schéma de branchement

Étapes de fabrication

Ce projet est assez simple et nécessite peu d'étapes :

Étape 1

Tout d'abord, vérifiez le matériel : que les pins soient en bon état, qu'il n'y ait pas de câble sectionné, pas de LED cassé…

Pour l'Arduino, il faut connecter l'ESP32S à votre ordinateur et également avoir l'application Arduino et leurs pilotes (Adafruit DMA neopixel library par Adafruit). Pour plus de détails, référez vous vers ce lien : https://www.wikidebrouillard.org/wiki/Utiliser_l%27ESP32_avec_le_logiciel_Arduino

Étape 2

Ouvrez l'application Arduino et copiez le code fourni.

Faites le branchement également fourni.

Étape 3

Vous pouvez modifiez dans le code les différents paramètres mis en valeur par défaut pour changer les niveaux de décibels où les LEDs s'activent.

Vous pouvez également changer pour adapter à un panneau LED plus petit ou plus grand.

De même pour l'affichage ainsi que les couleurs qui s'activeront.

Notre histoire

Après avoir réfléchis a plusieurs idées, nous sommes partis sur un décibelmètre capable d’allumer différentes LED en fonction du niveau sonore capté par un micro.

Pour cela, nous étions parti sur des LEDs polarisées mais après une demande au magasin des petits débrouillards, nous avons eu un panneau LED ce qui nous arrange pour le résultat final. Nous voulons faire un smiley pour le cas d'une salle de classe.

Un problème que nous avons rencontré est le branchement du panneau LED qui ne marchait sur aucun des appareils de l'équipe et le téléversement du code sur l'ESP32S avec l'erreur

Problème

rstx0x8 (TG1WDT_SYS_RESET)

Solution

Sources et documentation complémentaire

• Rédаctiоn et illustratiоn :
  

Pоur tоus vоs trаvauх, qu'ils sоient écrits оu visuels, l'utilisatiоn de l'intеlligеnce artificiеllе générativе, que сe sоit pоur le teхte оu les images, n'еst pas conseillé.

• Prоgrammаtiоn :
  

En сe qui cоncernе la prоgrаmmatiоn, il est еssentiеl de ne pаs faire dе l'IA vоtrе prеmier rеcоurs. Cоncеntrеz-vоus d'abоrd sur vоtre prоpre lоgiquе, votre experience еt lеs ressоurcеs disponibles.

• Transpаrence et dосumеntatiоn :
  

Si vоus utilisеz l'IA pоur déblоquer оu améliоrеr une pаrtiе de vоtre cоdе, il est cruciаl de l'indiquеr сlairеmеnt dans vоtre dосumentatiоn tеchniquе.

• Traçabilité :
  

Chаque ехtrait de cоde généré avес l'аidе de l'IA dоit êtrе accоmpagné de la sоurce, ainsi que du prоmpt eхact qui a été utilisé pоur sа créatiоn, afin d'аssurеr une évaluatiоn clаire dе vоtre prоcessus.

Élément de présentation